Right Click on BrowseFoldersDlg

RussWilmott

I'm using SDK8.0 with MSWord2003.

If I display the IIntegration.BrowseFoldersDlg I get the browse window just like in Desksite 8.

However, I need to capture a Right_Click event, as in Desksite 8, so that I can display an options menu, just like Desksite 8.

There appears to be no right_click events in the BrowseFoldersDlg object.

Am I using the wrong dialog? Or is there another way to achieve this?

Russ

jny

Use the IMANEXT2Lib.IManBrowseCmd instead.

[VB Example]

Option Explicit

Private Sub Form_Load()
Dim idms As New ManDMS
Dim isess As IManSession
Dim icmd As IMANEXT2Lib.IManBrowseCmd
Dim iContext As ContextItems
Dim arrSess(0) As NRTSession
Dim arrSelectableItems() As imObjectType
Dim retSelectedItem As Variant

On Error GoTo OOPS

Set isess = idms.Sessions.Add("server")
isess.TrustedLogin

Set arrSess(0) = isess

' Select object types
ReDim arrSelectableItems(0 To 1)
arrSelectableItems(0) = imObjectType.imTypeDocument
arrSelectableItems(1) = imObjectType.imTypeDocumentFolder

Set icmd = New IManBrowseCmd
Set iContext = New ContextItems

' Add required values
iContext.Add "NRTDMS", idms
iContext.Add "SelectedNRTSessions", arrSess
iContext.Add "ParentWindow", Me.hWnd
iContext.Add "IManExt2.BrowseCmd.SelectableObjectTypes", arrSelectableItems
' This determines which types of objects user is allowed to select

' Run command
icmd.Initialize iContext
icmd.Update
icmd.Execute

Dim blRefresh
blRefresh = iContext.Item("IManExt.Refresh")

' Returns true if user has selected an item.
If blRefresh = True Then
retSelectedItem = iContext.Item("IManExt2.BrowseCmd.SelectedObjects")
Dim strLocation
Dim oselected As IManObject
Set oselected = retSelectedItem(0)
strLocation = oselected.ObjectID
End If

GoTo CLEANUP

OOPS:
MsgBox Err.Description
Err.Clear
GoTo CLEANUP

CLEANUP:
Set iContext = Nothing
Set icmd = Nothing
Set isess = Nothing
Set idms = Nothing
End
End Sub