Content Server Load balancing with proximity value as 1

dctm_2012

We are currently implementing Documentum with two Content Server in HA and load balancing mode by setting PROXIMITY value as 1 in server.ini file on each content server. The Documentum Content  Server Administration and Installation guide 6.7 says that if we use above setting DFC client will randomly select Content Server for session but I'm not convinced with this approach

Fellow Documentum Experts please suggest what algorithm / parameter / logic is used to decide this Random behavior of choosing content server. Are you convinced whether we can implement such HA and load balancing architecture which behaves randomly ?

Note: Customer is insisting that both Content Server should be evenly take users session load. We checked with EMC support they don't support F5 hardware for load balancing for Content Server product

Thank you for all your help

EDMS98

We use proximity of 1 in our 6.7 HA configuration where threeContent Servers project to three docbrokers that are visible to various clients. The DFC appears to do a decent job of spreading out the sessions among the three Content Servers.

Here's a dmawk script you can run to get a list of the client sessions.  It should help to evaluate if the session are well balanced.   Note that it uses a EXECUTE SHOW SESSION dql to collect the session information.  To run it, you'll need to update the variables for the repository name and dmadmin password.

#---------------------------------------------------------------------------------
#  SessionList.awk
#
#  Desc: writes out session information, include host PID #
#
#    dmawk -f SessionList.awk > session_report.txt
#
#---------------------------------------------------------------------------------

BEGIN {

#----------------------------
# docbase connect variables
#----------------------------

strDocbase    = ""
strUser       = "dmadmin"
strPswd       = ""

#---------------------------
#   variables 
#---------------------------

session            = ""
strExitFlag        = ""
strQryCmd1         = ""
strQryID           = ""
intSuccess         = 0
strCmd             = ""

intTotalSessionCnt = 0
intTotalActiveCnt  = 0
intTotalActiveCnt  = 0

strSessionUser     = ""
strPID             = ""                                            
strSessionID       = ""                                            
strStatus          = ""
strStartDate       = ""
strLastDate        = ""
strClientHost      = ""
strLastRPC         = ""
strHostNum         = ""

#---------------------------------
# add comments to the beginning
# of the report           
#---------------------------------

printf("%s",    "#  ");
printf("\n%s",  "#        -----  SessionList.awk  -----");
printf("\n%s",  "#  ");
printf("\n%s",  "#  This dmawk utility queries to find all   ");
printf("\n%s",  "#  the repository sessions, and then prints ");
printf("\n%s",  "#  basic information on each session.       ");
printf("\n%s",  "#  ");
printf("\n%s",  "#  ");
printf("\n%s",  "#  Starting the SessionList script...");
printf("\n%s",  "#   ");

#----------------------------
#  create the session
#----------------------------

session = dmAPIGet("connect," strDocbase "," strUser "," strPswd )
if (session == NULL)
   {
    printf("\n\n%s", "#  Connect failed, exiting. ");
    strExitFlag = "NOSESSION";
    exit
   }
  else
   {
    printf("\n%s%s%s", "#  Session established in docbase ", strDocbase, ".");
    printf("\n%s",  "#  ");
   }

strQryCmd1 = "execute show_sessions"

printf("\n%s",   "#  Running the following DQL...");
printf("\n%s",   "#  ");
printf("\n%s%s", "#  ", strQryCmd1);
printf("\n%s",   "#  ");
printf("\n%s",   "#   ");

strQryID = dmAPIGet("readquery," session "," strQryCmd1);
if (strQryID == NULL)
   {
    strExitFlag = "BADQUERY";
    printf("\n\n%s", "#  The DQL failed, exiting.");
    exit;
   }

printf("\n%s", "#  Query successful. Processing the query results...")
printf("\n%s", "#  ");
printf("\n%s", "   ");

#--------------------------------------
#  loop through the query results
#-------------------------------------

while (dmAPIExec("next," session "," strQryID ) > 0)
  {
   strSessionUser       = dmAPIGet("get," session "," strQryID ",user_name")
   strPID               = dmAPIGet("get," session "," strQryID ",pid")
   strSessionID         = dmAPIGet("get," session "," strQryID ",session")
   strDIB               = dmAPIGet("get," session "," strQryID ",db_session_id")
   strStatus            = dmAPIGet("get," session "," strQryID ",session_status")
   strStartDate         = dmAPIGet("get," session "," strQryID ",start")
   strLastDate          = dmAPIGet("get," session "," strQryID ",last_used")
   strClientHost        = dmAPIGet("get," session "," strQryID ",client_host")

   #----------------------------------
   # print details on each session
   #----------------------------------

   printf("\n%s%s", "User Name ............... ", strSessionUser);
   printf("\n%s%s", "PID ..................... ", strPID);
   printf("\n%s%s", "DCTM Session ID ......... ", strSessionID);
   printf("\n%s%s", "Docbase Session ID ...... ", strDIB);
   printf("\n%s%s", "Session Status .......... ", strStatus);
   printf("\n%s%s", "Session Start Date ...... ", strStartDate);
   printf("\n%s%s", "Session Last Used Date... ", strLastDate);
   printf("\n%s%s", "Client Host ............. ", strClientHost);
   printf("\n%s",  "  ");

   #-------------------------------------------
   # Collect statistics on the total number of 
   # sessions broken down by active/inactive,
   # and also collect some basic counts grouped
   # by client host
   #-------------------------------------------

   intTotalSessionCnt ++1;
   grpStrClientHost[strClientHost] = strClientHost;
   grpIntClientTotalCnt[strClientHost]++1;

   if (strStatus == "Active")
      {
       intTotalActiveCnt++;
       grpIntClientActiveCnt[strClientHost]++1;
      }
   else
      {
       intTotalInactiveCnt++;
       grpIntClientInactiveCnt[strClientHost]++1;
      }
  }

#----------------
# close the query
#----------------

intSuccess = dmAPIExec("close," session "," strQryID);
printf("\n\n\n%s%s", "#  Closing the collection ..... ", intSuccess);

#-------------------
# close the session
#-------------------

intSuccess = dmAPIExec("disconnect," session)
printf("\n%s%s",     "#  Disconnecting the session .. ", intSuccess);

exit;

}

END {
     if (strExitFlag == "NOSESSION")
       {
        printf("\n%s",  "#  ");
        printf("\n%s", "#  The End.");
        exit;
       }

     if (strExitFlag == "BADQUERY")
       {
        printf("\n%s",  "#  ");
        printf("\n%s", "#  The End.");
        exit;
       }

      #--------------------
      # print the results
      #--------------------

      strCmd = "disconnect," session
      intSuccess = dmAPIExec(strCmd)
      printf("\n%s",  "#  ");
      printf("\n%s",  "#  ");
      printf("\n%s%5.0f", "#  Total number of sessions .................... ", intTotalSessionCnt);
      printf("\n%s%5.0f", "#  Total number of active sessions ............. ", intTotalActiveCnt);
      printf("\n%s%5.0f", "#  Total number of inactive sessions ........... ", intTotalInactiveCnt);
      printf("\n%s",  "#  ");
     
      for (i in grpStrClientHost)
       {
        printf("\n%s%s",    "#  Sessions for host: ", grpStrClientHost[i]);
        printf("\n%s%5.0f", "#    Total number ............................. ", grpIntClientTotalCnt[i]);
        printf("\n%s%5.0f", "#    Total number active ...................... ", grpIntClientActiveCnt[i]);
        printf("\n%s%5.0f", "#    Total number inactive .................... ", grpIntClientInactiveCnt[i]);
        printf("\n%s",  "#  ");
       }
      
      printf("\n%s", "#  ");
      printf("\n%s", "#  SessionList.awk completed.");
      printf("\n%s", "#  The End.");
      printf("\n");

   }