nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

Global regeneration of files in teamsite : Aumation

chiksur

Hi All,

In our application we have around 1500 pages which needs to be re-generated daily.Currently we are regenerating them manually.They are all located in different folders within one workarea.We have to regenerate these pages daily on a nightly basis.One option we were thinking of doing is

1)To pass a filelist(Containing the list of all the files) to the iw-regen command so that all the pages can be re-generated without us doing them manually.

It would really be great if you can let me know the pro's and con's associated with this approach.
Please let me know if there are better appraoches to regenerate the file on a global basis by automating the process.

Find more posts tagged with

Comments

nipper

What platform

on Unix you can write a command:

find /default/main/branch/WORKAREA/workarea/ -type html -exec iwregen {} \;

On DOS you can write a Perl script like that. Easily scheduled.

Andy

ISCBorisB

Hi All,

In our application we have around 1500 pages which needs to be re-generated daily.Currently we are regenerating them manually.They are all located in different folders within one workarea.We have to regenerate these pages daily on a nightly basis.One option we were thinking of doing is

1)To pass a filelist(Containing the list of all the files) to the iw-regen command so that all the pages can be re-generated without us doing them manually.

It would really be great if you can let me know the pro's and con's associated with this approach.
Please let me know if there are better appraoches to regenerate the file on a global basis by automating the process.

Do not bother with the File List, it's hard to maintain List/Site referential integrity.

Write a script with the root Path parameter(s). Traverse Path recursively filtering in desired extensions.
Get File's EAs and regenerate those that happened to have TeamSite/Templating/PrimaryDCR and TeamSite/Templating/PrimaryPT.
Depending on the regeneration mechanism you may have to (re)create some EAs.
Create generation manifest/log file for each run, may come very handy later on for intelligent Submissions and File List Deployments.

chiksur

Its a windows environment andy.

We want to do a nightly regeneration of all the teamsite DCR's.
Is there a way to differentiate between the good/bad DCR's.
Thanks a lot for your help.

Sailesh

Why you want to regenerate DCR's, if you are mean generated pages (HTML or jsp etc...) then you do not need to check good or bad dcr's; just run loop through your directories and check for files extended attributes, if they are teamsite generated files regenerate them.

gir

Hi,
I have used this method of regeneration. This method is useful when u have attributes set for the htmls and when u know that all the htmls are getting regenerated properly.

Problem with this approach is suppose a html is not getting regenerated then it is difficult for you to get to know which one. In order to get info on this it is better to keep a log while regenerating html files.

Overall it is worth regenerating using this command as it saves a lot of time and effort.

gzevin

Hi All,

In our application we have around 1500 pages which needs to be re-generated daily.Currently we are regenerating them manually.They are all located in different folders within one workarea.We have to regenerate these pages daily on a nightly basis.One option we were thinking of doing is

1)To pass a filelist(Containing the list of all the files) to the iw-regen command so that all the pages can be re-generated without us doing them manually.

It would really be great if you can let me know the pro's and con's associated with this approach.
Please let me know if there are better appraoches to regenerate the file on a global basis by automating the process.

all depends on your files' interdependency as well. I mean that some files might need to be generated ahead of the others, etc.

anyway, I have written by now a few scripts, both CGI and CLT that do it. depending on different templating structure.

abiondo

I was trying to figure this out too. We are running Windows 2003. I wrote something in VBscript that I think will do what you wanted. Save text to a file and save with the .vbs extension. Follow the instructions and you should be good.

[PHP]
' ###############################################################################################################
'
' IwRegen - Interwoven Regeneration Script
' Description: This script iterates the directory structure and looks for files with specific extensions and
' issues the IWREGEN command against the files. This script eases upgrades to your presentation
' templates that must be made across all pages in your website.
'
' Author: Anthony J Biondo Jr - CPHIMS, MCP (anthony.biondo@amerihealthmercy.com)
' Last Mod: March 20, 2009
' Version: 1.0
' Compatible: Interwoven TeamSite 6.7.2
'
' Setup:
'
' STEP 1: Update the configuration parameters based on your machine directories.
'
' STEP 2: Update the IncludeExtension Function to match your generated file extensions
'
' STEP 3: Update the FileExclusion Function to exclude filenames or filename patterns you want to exclude
'
'
' ###############################################################################################################
'
' DIMENSION VARIABLES
Dim objFSO
Dim CommandList
'
' CONFIGURATION PARAMETERS - HELP INFORMATION BELOW
TRACE_FILE_LOCATION = "trace.txt"
START_FOLDER = "Y:\default\main\branch\WORKAREA\content"
' HELP INFORMATION **********************************************************************************************
'
' PARAMETER DESCRIPTION
' ================== ================================================================================
' TRACE_FILE_LOCATION WHERE THE TRACE FILE IS STORED
' START_FOLDER PATH TO THE Y DRIVE CONTENT AREA OR FOLDER WITHIN THE CONTENT AREA TO REGENERATE
'
' ****************************************************************************************************************
' ************************************* DO NOT CONFIGURE BELOW THIS POINT ****************************************
' ****************************************************************************************************************
' ****************************************************************************************************************

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(START_FOLDER)
Set colFiles = objFolder.Files

CommandList = CommandList & "ECHO IWREGEN SITE UTILITY" & vbcrlf
CommandList = CommandList & "ECHO Start Folder: " & START_FOLDER & vbcrlf
MSGBOX(CommandList)

For Each objFile in colFiles
if IncludeExtension(objFSO.GetExtensionName(objFile.Name)) = 1 then
if ExcludeFiles(objFolder & "\" & objFile.Name) = 0 then
CommandList = CommandList & FormatOutput(objFolder.Path & "\" & objFile.Name) & vbcrlf
End If
End If
Next
' Call recursive Function passing the base folder
ShowSubfolders objFSO.GetFolder(START_FOLDER)

' Write Command List to a File for later execution
WriteFileText(CommandList)
' Notify the Use that the scrip is complete
MsgBox("Done")

' #############################################################################
' ShowSubFolders
' Description: Recursive Function that takes a folder and gets a list of
' files in subfolders.
'
' Inputs:
' Folder - Parent Folder
'
' Outputs:
' Nothing. Builds Command List
' #############################################################################
Sub ShowSubFolders(Folder)
For Each Subfolder in Folder.SubFolders
' objLogFile.Write Subfolder.Path & "\" & objFile.Name
' objLogFile.Writeline
Set objFolder = objFSO.GetFolder(Subfolder.Path)
Set colFiles = objFolder.Files
For Each objFile in colFiles
if IncludeExtension(objFSO.GetExtensionName(objFile.Name)) = 1 then
if ExcludeFiles(Subfolder.Path & "\" & objFile.Name) = 0 then
CommandList = CommandList & FormatOutput(Subfolder.Path & "\" & objFile.Name) & vbcrlf
End If
End If

Next
ShowSubFolders Subfolder
Next
End Sub

' #############################################################################
' FormatOutput
' Description: Returns an IW path to the location entered without a trailing
' slash.
'
' Inputs:
' s - Path to a Work Area or folder within a work area
'
' Outputs:
' FormatOutput = "/default/main/branchname/WORKAREA/myworkarea"
' #############################################################################
Function FormatOutput(s)
s = Replace(s, "Y:\", "/")
s = Replace(s, "\", "/")
FormatOutput = "iwregen " & chr(34) & s & chr(34)
End Function

' #############################################################################
' IncludeExtension
' Description: Extensions you wish to include in the search.
'
' Inputs:
' x - Valid file extension
'
' Outputs:
' IncludeExtension = 1 - True (Include Extension in Search)
' IncludeExtension = 0 - False (Exclude Extension from Search)
' #############################################################################
Function IncludeExtension(x)
select case LCase(x)

case "aspx"
IncludeExtension = 1
case else
IncludeExtension = 0
end select
End Function

' #############################################################################
' ExcludeFiles
' Description: Function used to exclude files from the return.
'
' Inputs:
' x - File Name
'
' Outputs:
' ExcludeFiles = 1 - True (Exclude Files from Search)
' ExcludeFiles = 0 - False (Include Files in Search)
' #############################################################################
Function ExcludeFiles(x)
If Instr(x, "zz_tst_") then
ExcludeFiles = 1
End If
End Function

' #############################################################################
' WriteFileText
' Description: Writes text to a file.
'
' Inputs:
' sText - String of text to be written.
'
' Outputs:
' Nothing
' #############################################################################
Function WriteFileText(sText)
Dim objFSO 'As FileSystemObject
Dim objTextFile 'As Object
Dim sFilePath

Const ForReading = 1
Const ForWriting = 2
Const ForAppending = 8
sFilePath = "IWGENSITE.CMD"
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(sFilePath, 2, True)
' Writes strText every time you run this VBScript
objTextFile.WriteLine(sText)
objTextFile.Close
End Function

[/PHP]