Moving documents between databases

jasonb_UK

Hi there,

I am attempting to use the SDK to write a vb.net module that will allow me to silently move content between multiple Worksite 8.2 content databases in a scheduled unattended process.

Before I go too far in the wrong direction, I just wanted to check my proposed method is sensible, or if a better alternative exists.

My plan is to identify the content collection (on database A) and iterate through the items (moving them to database thus:

- open connection to database A
- get item and hold profile information
- export item to server filepath
- delete item from database A
- open connection to database B
- import item into database B with stored profile information
- create any necessary folder_item records in database B
- close connections and tidy up
- process next item

Is this a sensible plan?

I'm new to the SDK, so not terribly familiar with all the methods available.

Thanks!

jny

You may use the ImportCmd to silently import a copy of the source document to another database. This, however, will not copy the metadata from the source profile; it only copies the Author, Operator, and the application type.

The code would look something like this:

[VB]
=============================

Dim dms As New ManDMS
Dim sess As IManSession
Dim srcDB As IManDatabase
Dim destDB As IManDatabase
Dim srcDoc As IManDocument
Dim importedDoc As IManDocument
Dim sPath As String
Dim i As Long

Dim context As IMANEXTLib.ContextItems
Dim cmd As IMANEXTLib.ImportCmd

On Error GoTo ERROR_HANDLER

' Login as administrator to get full access rights
Set sess = dms.Sessions.Add("servername")
sess.TrustedLogin
' Or explicit login
'sess.Login "NRTADMIN", "PASSWORD"

' Get source database
Set srcDB = sess.Databases.ItemByName("databasename")

' Get destination database
Set destDB = sess.Databases.ItemByName("databasename")

' Assuming you're copying a single document, _
' get source document by docnum and version.
Set srcDoc = srcDB.GetDocument(437, 1) 'Arbitrary example of a valid document number and version

' Example of a fullpath to download the source document file.
sPath = "C:/Temp/" & srcDoc.Number & "_" & srcDoc.Version & "_Copy" & "." & srcDoc.Extension

' Download a copy of the source document to the specified path.
srcDoc.GetCopy sPath, nrNativeFormat

Set context = New IMANEXTLib.ContextItems

' The WorkSite object you pass in should be the target server.
context.Add "IManDestinationObject", destDB

'to be able to use "IManExt.Import.DuplicateProfileFromDoc, _
IManExt.OpenCmd.NoCmdUI needs to be set to true.
context.Add "IManExt.OpenCmd.NoCmdUI", True

'srcDoc points to a valid document object.
context.Add "IManExt.Import.DuplicateProfileFromDoc", srcDoc

'filename set here is the checkedout path of the source doc.
context.Add "IManExt.Import.FileName", sPath

'example of a valid document class for the destination document profile
context.Add "IManExt.Import.DocClass", srcDoc.Class.Name

'example of a doc's description for the destination document profile
context.Add "IManExt.Import.DocDescription", "Copy from: [" & srcDoc.Database.Name & "] " & srcDoc.Number & "_" & srcDoc.Version 'the new document Description

Set cmd = New IMANEXTLib.ImportCmd
cmd.Initialize context
cmd.Update

' Use bitwise operation to check condition.
If cmd.Status = (cmd.Status And nrActiveCommand) Then
cmd.Execute
' Get the imported document
Set importedDoc = context.Item("ImportedDocument")
MsgBox "A copy of the source document has been duplicated as document: " & importedDoc.Number
If Not importedDoc Is Nothing Then
' Delete source document from its database
srcDB.DeleteDocument srcDoc.Number, srcDoc.Version
End If
End If
GoTo Cleanup

ERROR_HANDLER:
MsgBox Err.Description
Err.Clear

Cleanup:
' If sPath exist, destroy it.
If sPath <> "" Then Kill (sPath)

' Logout and close app
If sess.Connected Then sess.Logout
dms.Close

' Free memory
Set context = Nothing
Set cmd = Nothing
Set dms = Nothing
Set sess = Nothing
Set srcDB = Nothing
Set destDB = Nothing
Set srcDoc = Nothing
Set importedDoc = Nothing

=============================

Note in this example it is copying a single document. In your case, you would repeat this code inside an iteration loop of a collection of documents you already have.

Are your metatdata indentical in both source and destination databases? If so, you would need to buffer the metadata beforehand, possibly through an array or collection, then use the IManDocument.SetAttributeByID Method to populate the destination document with them post import; that is, call the method off of the imported document object, i.e, importedDoc in the above code example.

See "COM Object for WorkSite Developer's Reference Manual" in your SDK for further details and examples on the SetAttributeByID Method.