Can any one tell me how to use the dialog box of the move command

MadhuRS

I need to get the dialog box used by move command.

jny

That would be the IManBrowseCmd (IManExt2.dll).

[VB]
Option Explicit

Private Sub Form_Load()
Dim idms As New ManDMS
Dim isess As IManSession
Dim icmd As IMANEXT2Lib.IManBrowseCmd
Dim iContext As ContextItems
Dim arrSess(0) As NRTSession
Dim arrSelectableItems() As imObjectType
Dim retSelectedItem As Variant

On Error GoTo OOPS
Set isess = idms.Sessions.Add("DMS_SERVER")
isess.TrustedLogin

Set arrSess(0) = isess
' This array determins the types of WorkSite objects
'user can select from the dialog
ReDim arrSelectableItems(1 To 4)
arrSelectableItems(1) = imTypeWorkArea
arrSelectableItems(2) = imTypeDocumentFolder
arrSelectableItems(3) = imTypeWorkspace
arrSelectableItems(4) = imTypeContent

Set icmd = New IManBrowseCmd
Set iContext = New ContextItems

' Add required values
iContext.Add "NRTDMS", idms
iContext.Add "SelectedNRTSessions", arrSess
iContext.Add "ParentWindow", Me.hWnd
iContext.Add "IManExt2.BrowseCmd.SelectableObjectTypes", arrSelectableItems
iContext.Add "IManExt2.MultiFileSelection", False
' Run command
icmd.Initialize iContext
icmd.Update
icmd.Execute

Dim blRefresh
blRefresh = iContext.Item("IManExt.Refresh")

' Returns true if user has selected an item.
If blRefresh = True Then
retSelectedItem = iContext.Item("IManExt2.BrowseCmd.SelectedObjects")
Dim strLocation
Dim oselected As IManObject
Set oselected = retSelectedItem(0)
strLocation = oselected.ObjectID
End If

GoTo CLEANUP

OOPS:
MsgBox Err.Description
Err.Clear
GoTo CLEANUP

CLEANUP:
Set iContext = Nothing
Set icmd = Nothing
Set isess = Nothing
Set idms = Nothing
End
End Sub